Gainer/加速度センサ

import processing.gainer.*;

Gainer gainer;
PFont myFont;

//移動平均法フィルタ
MovingAverageFilter maFilterX;
MovingAverageFilter maFilterY;
MovingAverageFilter maFilterZ;

//---------------
int xMin = 75;  //最小値
int xMax = 184;  //最大値

//----------------
int yMin = 75;  //最小値
int yMax = 184;  //最大値

//初期化関数
void setup() {
  //ウィンドウサイズ設定
  size(300, 500);
  
  //フォント初期化
  myFont = loadFont("Eureka90.vlw");
  textFont(myFont, 24);
  
  //Gainerオブジェクト生成
  gainer = new Gainer(this);
  
  //アナログポートの状態をanalogInput[]に取得し続ける
  gainer.beginAnalogInput();
  
  //移動平均法フィルタオブジェクト生成
  maFilterX = new MovingAverageFilter(16);
  maFilterY = new MovingAverageFilter(16);
  maFilterZ = new MovingAverageFilter(16);
}

void draw()
{
  int aveX = 0;
  int aveY = 0;
  int aveZ = 0;
  float xInDegree = 0.0;
  float yInDegree = 0.0;
  
  //背景色設定
  background(0);
  
  gainer.peekAnalogInput();
  
  //センサ値取得
  int rawX = gainer.analogInput[0];
  int rawY = gainer.analogInput[1];
  int rawZ = gainer.analogInput[2];
  
  //フィルタリング処理
  aveX = maFilterX.processSample(rawX);
  aveY = maFilterY.processSample(rawY);
  aveZ = maFilterZ.processSample(rawZ);
  
  //センサ値（未加工）表示
  text("rawX: " + rawX, 10, 50); 
  text("rawY: " + rawY, 10, 80);
  text("rawZ: " + rawZ, 10, 110);
  
  //角度取得
  xInDegree = getDegree(aveX, xMin, xMax);
  yInDegree = getDegree(aveY, yMin, yMax);
  
  //センサ値（フィルタリング後）表示
  text("averagedX: " + aveX, 10, 170);
  text("averagedY: " + aveY, 10, 200);
  text("averagedZ: " + aveZ, 10, 230);
  
  //角度表示
  text("deg1: " + round(xInDegree), 10, 290); 
  text("deg2: " + round(yInDegree), 10, 320);
}

//角度計算関数
float getDegree(int in, int min, int max)
{
  float theta = 0;
  
  //スケーリング
  theta = map(in, min, max, -1.0, 1.0);
  
  //上限・下限を超えた場合の処理
  if(theta >= 1.0)
  {
    theta = 1.0;
  }
  else if(theta <= -1.0)
  {
    theta = -1.0;
  }
  
  //角度計算
  float deg = asin(theta)/ PI * 180.0;
  
  return deg;
}

//移動平均法クラス
public class MovingAverageFilter
{
  int taps;
  float[] values;
  
  //コンストラクタ
  public MovingAverageFilter(int requestedTaps)
  {
    taps = requestedTaps;
    values = new float[taps];
  }
  
  //フィルタリング処理
  int processSample(int in)
  {
    float acc = 0;
    values[0] = in;
    
    for(int i = 0; i < taps; i++)
    {
      acc += values[i];
    }
    acc /= taps;
    
    for(int i = taps - 1; i > 0; i--)
    {
      values[i] = values[i - 1];
    }
    return round(acc);
  }
}